// Este es ejemplo de sistema complejo, en donde un grupo muy grande de hormigas (representadas por cículos
// pequeños negros) son comidas por una círculo rojo. Las comidas quedan en el camino de color gris.
// Haciendo click la escena aranca de cero.
// Tanto las hormigas como el círculo rojo están hechas con el mismo objeto y sólo difieren en el tipo
// de ordenes que recibe por parte del programa principal (void loop).
//
// Emiliano Causa
// Julio 2006
// www.emiliano-causa.com.ar
//----------------------------------------------------------
Hormiga[] estaHormiga; //define un verctor de objetos "Hormiga"

int canti;  //define la cantidad de hormigas
int voraz;  //con esta variable se define cuál será la hormiga roja que comerá a las demás
//----------------------------------------------------------
void setup(){
  size(600,400);

  canti = 3000;    //cantidad de hormigas
  voraz = canti - 1;  //la última hormiga es el círculo rojo que comerá a las demás (la voraz)
  estaHormiga = new Hormiga[canti];  //genera el espacio de memoria para el vector
  iniciarTodo();   //ejecuta una función que inicializa las variables
}
//----------------------------------------------------------
void loop(){
  background(250);

  for(int i=0 ; i<canti ; i++){   //recorre todas las hormigas para ver sual es comida por la voraz (circulo rojo)
    if(i != voraz)                                       //si esta hormiga NO es la voraz (circulo rojo) entonces
    estaHormiga[voraz].intentarComer( estaHormiga[i] );  //prueba para ver si la voraz se la puede comer
  }

  for(int i=0 ; i<canti ; i++){                  //recorre todas las hormigas
    if(i != voraz ){
      estaHormiga[i].huir( estaHormiga[voraz] ); //si es una hormiga común entonces huye de la voraz
    }else{
      estaHormiga[i].mover();                    //en cambio, si es la voraz se mueve al azar
    }
    estaHormiga[i].dibujar();                    //dibuja cada hormiga
  }

}
//----------------------------------------------------------
void mousePressed(){
  iniciarTodo();        //si se presiona el botón del mouse se reinicia todo
}
//----------------------------------------------------------
void iniciarTodo(){     //esta funciona es la que inicializa todas las hormigas
  for(int i=0 ; i<canti ; i++){    //recorre cada hormiga
    estaHormiga[i] = new Hormiga(random(200,400),random(100,300),random(2,7),50);    //le asigna una posición al azar dentro del cuadrado
    // (200,100) (400,300)
    estaHormiga[i].radio = 2;    //le asigna a cada hormiga un radio de 2 píxeles
    if(i==voraz){                                         //si la hormiga es voraz
      estaHormiga[i].cambiarColor( color(255,0,0) );      //le asigna el color rojo
      estaHormiga[i].vel = 10;                            //le da mayor velocidad
      estaHormiga[i].radio = 20;                          //y mayor tamaño
    }
  }
}

//----------------------------------------------------------
class Hormiga{     //clase que define a las hormigas
  float x, y;      //posición de la hormiga
  float radio;     //tamaño
  float angulo;    //dirección hacia donde avanza
  float vel;       //velocidad con la que avanza
  float apertura;  //apertura de angulo con la que varía su dirección
  color relleno;   //color de la hormiga

  boolean estaViva;  //esta variable es para definir si la hormiga esta viva o muerta

  Hormiga(){  //constructor que inicia la hormiga con una posición al azar en la pantalla,
    //una velocidad de 1 pixel/frame y una apertura de cambio de direccion de 30 grados
    iniciar(random(width),random(height),1,30);  //todos los constructores llaman a una misma función "iniciar()"
  }

  Hormiga(float x, float y){  //constructor en donde le puedo pasar la posición inicial de la hormiga
    iniciar(x,y,1,30);
  }

  Hormiga(float x, float y, float vel, float apertura){  //constructor donde le paso todos los parámetros
    iniciar(x,y,vel,apertura);
  }

  void iniciar(float x, float y, float vel, float apertura){  //funcion que inicializa la hormiga
    this.x = x;  //posicion horizontal
    this.y = y;  //posicion vertical
    radio = 5;   //tamaño
    angulo = random(360);  //define la dirección inicial al azar
    this.vel = vel;    //velocidad definida en píxeles/frames
    this.apertura = apertura;  //apertura de la dirección
    relleno = color(0,0,0);    //el color inicial es negro
    estaViva = true;    //se inicia viva
  }

  void intentarComer(Hormiga otra){    //esta funcion es para comer otra hormiga
    if( otra.estaViva ){    //revisa que la otra esté viva
      if( dist(x , y , otra.x , otra.y ) < radio + otra.radio ){ //revisa si la distancia le permite tocar a la otra
        otra.morir();    //si esta al alcance, la mata
      }
    }
  }

  void cambiarColor(color esteColor){   //esta funcion permite cambiar el color de la hormiga
    relleno = esteColor;
  }

  void morir(){      //esta funcion es para matarla
    estaViva = false;
  }

  void huir(Hormiga otra){        //esta función es para huir de otra
    if(estaViva){      //para huir primero tiene que estar viva
      if( dist(x,y,otra.x,otra.y) < random(100,200) ){  //decide una dirección de huida, sólo si esta cerca de la otra
        angulo = degrees( atan2( y - otra.y , x - otra.x ) );    //averigua la dirección de huida en función del ángulo entre ella y la otra
        angulo += random( -apertura * 2 , apertura * 2 );    //le agrega una variación de ángulo al azar para que no parezcan robots
      }
      mover();  //se mueve en esa dirección
    }

  }

  void mover(){      //mueve a la hormiga
    if(estaViva){    //para moverse primero tiene que estar viva
      float incX = vel * cos( radians( angulo ));  //define el incremento horizontal en funcion de la dirección y la distancia
      float incY = vel * sin( radians( angulo ));  //define el incremento vertical en funcion de la dirección y la distancia

      angulo += random(-apertura,apertura);    //le agrega una variación de ángulo al azar para que no parezcan robots

      x+=incX;  //aplica el incremento a la posición actual para moverlo
      y+=incY;

      x = (x > width ? 0 : x);  //revisa si se pasa de los bordes para hacerla reingresar por el borde opuesto (espacio Toroidal)
      x = (x < 0 ? width : x);
      y = (y > height ? 0 : y);
      y = (y < 0 ? height : y);
    }
  }

  void dibujar(){   //dibuja la hormiga
    noStroke();
    ellipseMode(CENTER_DIAMETER);

    if(estaViva){    
      fill(relleno);   //si esta viva la pinta del color de relleno
    }else{
      fill(155,50);   //si esta muerta la pinta de gris transparente
    }
    ellipse( this.x , this.y , radio * 2 , radio * 2 );  //dibuja el círculo de la hormiga

  }

}