// Emiliano Causa 
// 23/Jun/2006
// Inercia y amortiguación
Seguidor[] pepe;
float factorAmortigua;
float factorInercia;

int cant;
void setup(){
  size(800,400);
  cant = 100;
  
  factorAmortigua = 0.7;
  factorInercia = 0.17;


  pepe = new Seguidor[cant];

  for(int i=0 ; i<cant ; i++){
    pepe[i] = new Seguidor();
  }

}
void loop(){
  background(0);

  pepe[0].seguir();
  for(int i=1 ; i<cant ; i++){
    pepe[i].seguir( pepe[i-1] );
  }

  for(int i=0 ; i<cant ; i++){
    pepe[i].dibujar();
  }

}

class Seguidor{
  float x , y;
  float psaltox,psaltoy;
  float saltox,saltoy;

  Seguidor(){
    iniciar( random(width) , random(height) );
  }
  void iniciar(float x_,float y_){
    x = x_;
    y = y_;
  }

  void seguir(Seguidor otro){
    seguir( otro.x , otro.y );
  }

  void seguir(){
    seguir(mouseX,mouseY);
  }

  void seguir(float x_, float y_){
    if( dist(x,y,x_,y_) > 1){
      saltox = x_ - x;
      saltoy = y_ - y;
    
      x += amortiguar( saltox * factorAmortigua, psaltox , factorInercia);
      y += amortiguar( saltoy * factorAmortigua, psaltoy , factorInercia);      
      
      psaltox = saltox;
      psaltoy = saltoy;
    }
  }

  float amortiguar(float actual, float nuevo, float factor){
    return nuevo * factor + actual * (1- factor);
  }

  void dibujar(){
    ellipseMode(CENTER_DIAMETER);
    noStroke();
    float distancia = dist(0,0,saltox,saltoy);
    fill(0,0,255,distancia * 2);
    ellipse(x,y,distancia / 10 + 20 , distancia / 10 + 20);
  }

}